#include <Wire.h>//I2Cを使用
#include <LiquidCrystal.h>//LCDを使用
#include <DS3231.h>//RTCを使用
#include <DHT.h>//DTHを使用

​

#define MPL115A2 0x60//気圧計のI2Cアドレス
#define num 100//num回の平均をとる
#define DHTPIN A3//入力用のPIN
#define DHTTYPE DHT11//型名

LiquidCrystal lcd(8,9,4,5,6,7);//液晶作成

DS3231 RTC;//RTCを作る
DHT dht(DHTPIN, DHTTYPE);//dhtを作成

byte year, month, date, DoW, hour, minute, second,prevSecond;
float a0,b1,b2,c12;//気圧の係数のための変数
float Press,Temp;//気圧と気温の変数

​

void setup() {
  Serial.begin(9600);//serial初期化
  Wire.begin();      //wire初期化
  lcd.begin(16, 2);
  dht.begin();//dhtスタート
  Coefficient();//補正係数取得
  delay(3000);//3秒待ち
}

​

void loop() {
  float p=0;//pは浮動小数
  int h = dht.readHumidity();
  int t = dht.readTemperature();
  //時刻の取得
    RTC.getTime(year, month, date, DoW, hour, minute, second);
    if (prevSecond != second) {//以前の秒と違ったとき
  //年表示

  lcd.setCursor(0, 0); //年表示

  lcd.print("20");

  lcd.print(year);

  lcd.print("y");

  //日付表示

  if(month<10){lcd.print(" ");}

  lcd.print(month);

  lcd.print("/");

  if(date<10){lcd.print(" ");}

  lcd.print(date);

  //曜日の表示
  lcd.setCursor(0, 1);
  switch (DoW) {
         case 1:lcd.print("Sn");break;
         case 2:lcd.print("Mo");break;
         case 3:lcd.print("Tu");break;
         case 4:lcd.print("We");break;
         case 5:lcd.print("Th");break;
         case 6:lcd.print("Fr");break;
         case 7:lcd.print("St");break;
         default:lcd.print("??");break;
}
  //時刻の表示
      lcd.setCursor(2, 1);
      if(hour<10){lcd.print(" ");}
      lcd.print(hour);lcd.print(":");
      if(minute<10){lcd.print("0");}
      lcd.print(minute);lcd.print(":");
      if(second<10){lcd.print("0");}
  lcd.print(second);
  prevSecond=second;//以前の秒を現在の秒に変更

  //気圧の平均取得
    for( int i=0;i<num;i++){
      PressTemp();
      p=p+int (Pressure());}//積算
    if (isnan(h) || isnan(t)) {
      return;  }//h,tが数字でなければERROR帰還
    Press=p/num;//平均
//気圧の表示
    lcd.setCursor(11, 0);//ｷｱﾂ
    if(Press<1000){lcd.print(" ");}
    lcd.print(int(Press));
    lcd.print("h");//ｷｱﾂ
//気温表示
  lcd.setCursor(11, 1);//ｷｵﾝ
  if(t<10){lcd.print(" ");}
  lcd.print(t);
  lcd.print("\xdf");//ｷｵﾝ
//湿度表示
  lcd.setCursor(14, 1);//ｼﾂﾄﾞ
  if(h<10){lcd.print(" ");}
  lcd.print(h);
  lcd.print("%");//ｼﾂﾄﾞ
    }
}

​

//関数・補助部

​

int Coefficient(){//係数読み込み
  unsigned int u,l;//ulは２ＢＹＴＥ数
  Wire.beginTransmission(MPL115A2);
  Wire.write(0x04);//04番地から読みます
  if(Wire.endTransmission()!=0)return 5;//0でなければ失敗帰還
    if(Wire.requestFrom(MPL115A2,8)!=8)return 5;//失敗なら帰還 
//係数a0,b1,b2,c12を読み込む 
      //a0の読み込みと計算
      u=Wire.read();l=Wire.read();
      // a0 = (u << 5) + (l >> 3) + (l & 0x07) / 8.0 ;
      a0=((u << 8) + l ) / 8.0 ;
      if( u & 0x80 ) a0 -= 8192.0;
 
      //b1の読み込みと計算
      u=Wire.read();l=Wire.read();
      //b1 = ( ( ( (u & 0x1F) * 0x100 ) + l ) / 8192.0 ) - 3 ;
      b1 = ( ( u <<8) + l ) / 8192.0 ;
      if( u & 0x80 ) b1 -= 8.0;
      
      //b2の読み込みと計算
      u=Wire.read();l=Wire.read();
 //b2 = ( ( ( ( u - 0x80) << 8 ) + l ) / 16384.0 ) - 2 ;
      b2 = ( (u << 8 ) + l ) / 16384.0 ;
      if( u & 0x80 ) b2 -= 4.0;
      
      //c12の読み込みと計算
      u=Wire.read();l=Wire.read();
      //c12 = ( ( ( h * 0x100 ) + l ) / 16777216.0 )  ;
      c12 = ( ( u <<8) + l ) / 32768.0 ;
      if( u & 0x80 ) c12 -= 2.0;
      c12 /= 512.0;
   return 0;
}

​

int PressTemp(){//気圧と気温を測定
  unsigned int u,l;
 
  Wire.beginTransmission(MPL115A2);
  Wire.write(0x12);//気圧と気温のAD変換開始
  Wire.write(0x01);
  if(Wire.endTransmission()!=0)return 5;//失敗はERROR5
  delay(3);//変換時間待ち

  Wire.beginTransmission(MPL115A2);//
  Wire.write(0x00);
  if(Wire.endTransmission()!=0)return 5;//失敗はERROR5帰還
    if(Wire.requestFrom(MPL115A2,4)!=4)return 5;//失敗はERR5帰還
    //気圧
    u=Wire.read();l=Wire.read();
    Press=((u<<8)+l)/64.0;//=(u*256+l)/64.0;
    //気温
    u=Wire.read();l=Wire.read();
    Temp=((u<<8)+l)/64.0;//=(u*256+l)/64.0;
  return 0;
}

​

float Pressure(){//補正された気圧を求める式
  float d;
 
  d=a0 + (b1 + c12*Temp )*Press + b2*Temp;
  return  d * ( 650.0 / 1023.0 ) + 500.0 ;
}